Class held_suarez_1994
In: held_suarez_1994/held_suarez_1994.f90

Held and Suarez (1994) ������綣桁�吟���ｉ��

Forcing and dissipation suggested by Held and Suarez (1994)

Note that Japanese and English are described in parallel.

Held and Suarez (1994) �ф�罅�������箙丞�ュぇ羂� GCM ���潟�����若������ 綣桁�吟���ｉ�吾��荐�膊����障��. 筝�����綣桁�吟���ｉ�吾������, 羝�墾�眼��遣�九�腱医�眼�吾��亜�������ャ�若���喝�桁�眼��, 紜���絮ゆ������茵�憗����筝�絮ら※�����ゃ���惹�����������障��. 荅括完��篁ヤ�������障��.

Forcing and dissipation for dry air GCM benchmark suggested by Held and Suarez (1994) are caluclate. We use simple Newtonian relaxation of the temperature field to a zonally symmetric state and Rayleigh damping of low-level winds to represent boundary-layer friction. Their specifications are detailed as follows.

\[ 

   \left( \DP{\Dvect{v}}{t} \right)_{\mathrm{HS94}} =
       - k_v (\sigma) \Dvect{v}, \] \[
   \left( \DP{T}{t} \right)_{\mathrm{HS94}} =
       - k_T (\phi, \sigma) [T - T_{eq} (\phi,p)], \] \[
   T_{eq} = \mathrm{max}
    \left\{
       200 \mathrm{K},
       \left[
         315 \mathrm{K} - (\Delta T)_y \sin^2\phi
                        - (\Delta \theta)_z
                          \log \left(\frac{p}{p_0}\right) \cos^2\phi
       \right] \left(\frac{p}{p_0}\right)^\kappa
    \right\}, \] \[
   k_T = k_a + (k_s - k_a)
         \mathrm{max}
         \left(0, \frac{\sigma - \sigma_b}{1 - \sigma_b}\right) \cos^4\phi,
    \] \[
   k_v = k_f
         \mathrm{max}
         \left(0, \frac{\sigma - \sigma_b}{1 - \sigma_b}\right),
    \] \[
   \sigma_b = 0.7, \qquad
   k_f = 1 \mathrm{day}^{-1}, \qquad
   k_a = \Dinv{40} \mathrm{day}^{-1}, \qquad
   k_s = \Dinv{4} \mathrm{day}^{-1}, \] \[
   (\Delta T)_y = 60 \mathrm{K}, \qquad
   (\Delta \theta)_z = 10 \mathrm{K}, \qquad
   p_0 = 1000 \mathrm{hPa}, \qquad
   \kappa = \frac{R}{c_p}.

\]

Forcing �с��, 筝�����������綺���羝�墾 ( $ t+Delta t$ ���喝�) �������札筝���������七�吟���ｉ�吾���������障��.

By Forcing, forcing and dissipation are applied to given wind and temperature ($ t+Delta t$ is expected) as follows.

\[ 

   \hat{\Dvect{v}}^{t+\Delta t} =
     \Dvect{v}^{t+\Delta t}
     + 2 \Delta t \left( \DP{\Dvect{v}}{t} \right)_{\mathrm{HS94}} \] \[
   \hat{T}^{t+\Delta t} =
     T^{t+\Delta t}
     + 2 \Delta t \left( \DP{T}{t} \right)_{\mathrm{HS94}}

\]

Procedures List

Hs94Forcing :綣桁�吟���ｉ�吾���膊�
Hs94Finalize :腟�篋����� (�≪�吾�ャ�若����������違���蚊��篁���茹ｉ��)
———— :————
Hs94Forcing :Calculate forcing and dissipation
Hs94Finalize :Termination (deallocate variables in this module)

References

  • Held, I. M., Suarez, M. J., 1994: A proposal for the intercomparison of the dynamical cores of atmospheric general circuation models. Bull. Am. Meteor. Soc., 75, 1825--1830.

Methods

DelPotTempZ   DelTempY   HS94Finalize   HS94Forcing   HS94Init   Kappa   P0   held_suarez_1994_inited   module_name   version   yz_kt   z_kv  

Included Modules

gridset dc_types dc_message axesset timeset gtool_historyauto constants namelist_util dc_iounit dc_string

Public Instance methods

HS94Finalize( )
Subroutine :

�≪�吾�ャ�若����������違���蚊��篁���茹ｉ�ゃ��茵����障��.

Deallocate variables in this module.

[Source]

  subroutine HS94Finalize
    !
    ! �≪�吾�ャ�若����������違���蚊��篁���茹ｉ�ゃ��茵����障��. 
    !
    ! Deallocate variables in this module. 
    !

    ! 絎ｈ��� ; Declaration statements
    !
    implicit none

    ! 絎�茵��� ; Executable statement
    !

    if ( .not. held_suarez_1994_inited ) return

    ! �蚊��篁���茹ｉ��
    ! Deallocation
    !
    if ( allocated( z_kv  ) ) deallocate( z_kv  )
    if ( allocated( yz_kt ) ) deallocate( yz_kt )

    held_suarez_1994_inited = .false.

  end subroutine HS94Finalize
HS94Forcing( xyz_U, xyz_V, xyz_Temp, xy_Ps, xyz_DUDt, xyz_DVDt, xyz_DTempDt )
Subroutine :
xyz_U(0:imax-1, 1:jmax, 1:kmax) :real(DP), intent(in)
: $ u $ . �沿タ蘂���. Eastward wind
xyz_V(0:imax-1, 1:jmax, 1:kmax) :real(DP), intent(in)
: $ v $ . ����蘂���. Northward wind
xyz_Temp(0:imax-1, 1:jmax, 1:kmax) :real(DP), intent(in)
: $ T $ . 羝�墾. Temperature
xy_Ps(0:imax-1, 1:jmax) :real(DP), intent(in)
: $ p_s $ . �域；�∽���. Surface pressure
xyz_DUDt(0:imax-1, 1:jmax, 1:kmax) :real(DP), intent(out)
: $ DP{u}{t} $ . �沿タ蘂���紊���. Eastward wind tendency
xyz_DVDt(0:imax-1, 1:jmax, 1:kmax) :real(DP), intent(out)
: $ DP{v}{t} $ . ����蘂���紊���. Northward wind tendency
xyz_DTempDt(0:imax-1, 1:jmax, 1:kmax) :real(DP), intent(out)
: $ DP{T}{t} $ . 羝�墾紊���. Temperature tendency

綣��違����������������沿タ蘂��� xyz_U, ����蘂��� xyz_V, 羝�墾 xyz_Temp ����, 羝�墾�眼��遣�九�腱医�眼�吾��亜�������ャ�若���喝�桁�眼�� 紜���絮ゆ������茵�憗����筝�絮ら※�����ゃ���惹���������� 蘂�����県綺����������羆���, xyz_DUDt, xyz_DVDt, xyz_DTempDt ������障��.

Tendencies by simple Newtonian relaxation of the temperature field to a zonally symmetric state and Rayleigh damping of low-level winds to represent boundary-layer friction are calculated from eastward wind "xyz_U", northward wind "xyz_V", temperature "xyz_Temp". And the tencencies are returned as "xyz_DUDt", "xyz_DVDt", "xyz_DTempDt".

[Source]

  subroutine HS94Forcing( xyz_U,    xyz_V,    xyz_Temp, xy_Ps, xyz_DUDt, xyz_DVDt, xyz_DTempDt )
    !
    ! 綣��違����������������沿タ蘂��� xyz_U, ����蘂��� xyz_V, 
    ! 羝�墾 xyz_Temp ����, 
    ! 羝�墾�眼��遣�九�腱医�眼�吾��亜�������ャ�若���喝�桁�眼��
    ! 紜���絮ゆ������茵�憗����筝�絮ら※�����ゃ���惹����������
    ! 蘂�����県綺����������羆���, 
    ! xyz_DUDt, xyz_DVDt, xyz_DTempDt ������障��. 
    !
    ! Tendencies by simple Newtonian relaxation of the temperature field to a
    ! zonally symmetric state and Rayleigh damping of low-level winds to
    ! represent boundary-layer friction are calculated 
    ! from eastward wind "xyz_U", northward wind "xyz_V", 
    ! temperature "xyz_Temp".
    ! And the tencencies are returned as 
    ! "xyz_DUDt", "xyz_DVDt", "xyz_DTempDt". 
    !
    !

    ! �≪�吾�ャ�若����� ; USE statements
    !

    ! 綺ф����若�粋┃絎�
    ! Axes data settings
    !
    use axesset, only: y_Lat, z_Sigma               ! $ \sigma $ ������ (�贋��). 
                              ! Full $ \sigma $ level

    ! ���紫���
    ! Time control
    !
    use timeset, only: DelTime, TimeN, TimesetClockStart, TimesetClockStop

    ! ���鴻�������若�水�阪��
    ! History data output
    !
    use gtool_historyauto, only: HistoryAutoPut

    ! 絎ｈ��� ; Declaration statements
    !
    implicit none

    real(DP), intent(in):: xyz_U (0:imax-1, 1:jmax, 1:kmax)
                              ! $ u $ . �沿タ蘂���. 
                              ! Eastward wind
    real(DP), intent(in):: xyz_V (0:imax-1, 1:jmax, 1:kmax)
                              ! $ v $ . ����蘂���. 
                              ! Northward wind
    real(DP), intent(in):: xyz_Temp (0:imax-1, 1:jmax, 1:kmax)
                              ! $ T $ . 羝�墾. 
                              ! Temperature
    real(DP), intent(in):: xy_Ps (0:imax-1, 1:jmax)
                              ! $ p_s $ . �域；�∽���. 
                              ! Surface pressure
    real(DP), intent(out):: xyz_DUDt (0:imax-1, 1:jmax, 1:kmax)
                              ! $ \DP{u}{t} $ . �沿タ蘂���紊���. 
                              ! Eastward wind tendency
    real(DP), intent(out):: xyz_DVDt (0:imax-1, 1:jmax, 1:kmax)
                              ! $ \DP{v}{t} $ . ����蘂���紊���. 
                              ! Northward wind tendency
    real(DP), intent(out):: xyz_DTempDt (0:imax-1, 1:jmax, 1:kmax)
                              ! $ \DP{T}{t} $ . 羝�墾紊���. 
                              ! Temperature tendency

    ! 篏�罐�����
    ! Work variables
    !
    real(DP):: xyz_TempEQ (0:imax-1, 1:jmax, 1:kmax)
                              ! $ T_{eq} $ . 綛活　羝�墾. 
                              ! Equilibrium temperature
    real(DP):: xyz_Press (0:imax-1, 1:jmax, 1:kmax)
                              ! $ T $ . �у��. 
                              ! Pressure

    integer:: j               ! 膩�墾�劫�������� DO ���若�����罐�����
                              ! Work variables for DO loop in latitude
    integer:: k               ! ���贋�劫�������� DO ���若�����罐�����
                              ! Work variables for DO loop in vertical direction

    ! 絎�茵��� ; Executable statement
    !

    ! ������腆肴�
    ! Initialization check
    !
    if ( .not. held_suarez_1994_inited ) then
      call MessageNotify( 'E', module_name, 'This module has not been initialized.' )
    end if

    ! 荐�膊�����荐�羝���紮�
    ! Start measurement of computation time
    !
    call TimesetClockStart( module_name )


    ! �沿タ蘂��� $ u $ ������蘂��� $ v $ �吾���ゃ���惹����������
    ! Apply Rayleigh damping to eastward wind $ u $ and northward wind $ v $
    !
    do k = 1, kmax
      xyz_DUDt (:,:,k) = - z_kv (k) * xyz_U (:,:,k)
      xyz_DVDt (:,:,k) = - z_kv (k) * xyz_V (:,:,k)
    end do

    ! 羝�墾 $ T $ �吾���ャ�若���喝�桁�眼������
    ! Apply Newtonian relaxation to temperature $ T $
    !
    do k = 1, kmax
       xyz_Press(:,:,k) = z_Sigma(k) * xy_Ps
    enddo

    do j = 1, jmax
      xyz_TempEQ(:,j,:) = max( 200.0_DP, (   315.0_DP - DelTempY * sin( y_Lat(j) ) ** 2 - DelPotTempZ * log( xyz_Press(:,j,:) / P0 ) * cos( y_Lat(j) ) ** 2 ) * ( xyz_Press(:,j,:) / P0 ) ** Kappa )
    end do

    do k = 1, kmax
      do j = 1, jmax
        xyz_DTempDt (:,j,k) = - yz_kt (j,k) * ( xyz_Temp (:,j,k) - xyz_TempEQ (:,j,k) )
      end do
    end do


    ! ���鴻�������若�水�阪��
    ! History data output
    !
    call HistoryAutoPut( TimeN, 'DUDtHS94',    xyz_DUDt )
    call HistoryAutoPut( TimeN, 'DVDtHS94',    xyz_DVDt )
    call HistoryAutoPut( TimeN, 'DTempDtHS94', xyz_DTempDt )
    call HistoryAutoPut( TimeN, 'TempEQHS94',  xyz_TempEQ )


    ! 荐�膊�����荐�羝������罩�
    ! Pause measurement of computation time
    !
    call TimesetClockStop( module_name )

  end subroutine HS94Forcing
HS94Init( )
Subroutine :

held_suarez_1994 �≪�吾�ャ�若������������茵����障��. NAMELIST#held_suarez_1994_nml ����粋昭�帥��������膓����ц�����障��.

"held_suarez_1994" module is initialized. "NAMELIST#held_suarez_1994_nml" is loaded in this procedure.

This procedure input/output NAMELIST#held_suarez_1994_nml .

[Source]

  subroutine HS94Init
    !
    ! held_suarez_1994 �≪�吾�ャ�若������������茵����障��. 
    ! NAMELIST#held_suarez_1994_nml ����粋昭�帥��������膓����ц�����障��. 
    !
    ! "held_suarez_1994" module is initialized. 
    ! "NAMELIST#held_suarez_1994_nml" is loaded in this procedure. 
    !

    ! �≪�吾�ャ�若����� ; USE statements
    !

    ! ����絎��域┃絎�
    ! Physical constants settings
    !
    use constants, only: GasRDry, CpDry
                              ! $ C_p $ [J kg-1 K-1]. 
                              ! 箙丞�ュぇ羂�����ф���. 
                              ! Specific heat of air at constant pressure

    ! 綺ф����若�粋┃絎�
    ! Axes data settings
    !
    use axesset, only: y_Lat, z_Sigma               ! $ \sigma $ ������ (�贋��). 
                              ! Full $ \sigma $ level

    ! NAMELIST ���＜�ゃ���ュ�����≪�������若���ｃ������
    ! Utilities for NAMELIST file input
    !
    use namelist_util, only: namelist_filename, NmlutilMsg, NmlutilAryValid

    ! ���＜�ゃ���ュ�阪��茖���
    ! File I/O support
    !
    use dc_iounit, only: FileOpen

    ! 腮��ュ�������＜��
    ! Kind type parameter
    !
    use dc_types, only: STDOUT ! 罔�羣��阪�����臀����. Unit number of standard output

    ! ��絖�����篏�
    ! Character handling
    !
    use dc_string, only: StoA

    ! ���鴻�������若�水�阪��
    ! History data output
    !
    use gtool_historyauto, only: HistoryAutoAddVariable

    ! 絎ｈ��� ; Declaration statements
    !
    implicit none

    real(DP), parameter :: day_seconds = 86400.0_DP
                              ! 1 �ャ�����. 
                              ! Seconds in day. 
    real(DP):: SigmaB         ! $ \sigma_b $ .
                              ! 紜���絮や�腴����綺�
    real(DP):: kf             ! $ k_f $ .
                              ! �域；�≪�с�� Rayleigh ������粂��篆���
    real(DP):: ka             ! $ k_a $ .
                              ! 紊ф�筝�絮ゃ�������� Newton �桁�眼��粂��篆���
    real(DP):: ks             ! $ k_s $ .
                              ! 莎ら���域；�≪�������� Newton �桁�眼��粂��篆���

    real(DP):: kfTimeScaleInDay
    real(DP):: kaTimeScaleInDay
    real(DP):: ksTimeScaleInDay

    integer:: j               ! 膩�墾�劫�������� DO ���若�����罐�����
                              ! Work variables for DO loop in latitude
    integer:: k               ! ���贋�劫�������� DO ���若�����罐�����
                              ! Work variables for DO loop in vertical direction

    integer:: unit_nml        ! NAMELIST ���＜�ゃ�����若���括���臀����. 
                              ! Unit number for NAMELIST file open
    integer:: iostat_nml      ! NAMELIST 茯���粋昭�炊���� IOSTAT. 
                              ! IOSTAT of NAMELIST read

    ! NAMELIST 紊��亥召
    ! NAMELIST group name
    !
    namelist /held_suarez_1994_nml/ SigmaB, kfTimeScaleInDay, kaTimeScaleInDay, ksTimeScaleInDay
          !
          ! �����������ゃ���ゃ��������������膓� "held_suarez_1994#HS94Init" 
          ! ���純�若�鴻�潟�若�������с������. 
          !
          ! Refer to source codes in the initialization procedure
          ! "held_suarez_1994#HS94Init" for the default values. 
          !

    ! 絎�茵��� ; Executable statement
    !

    if ( held_suarez_1994_inited ) return


    ! �����������ゃ��┃絎�
    ! Default values settings
    !
    SigmaB           =  0.7_DP
    kfTimeScaleInDay =  1.0_DP
    kaTimeScaleInDay = 40.0_DP
    ksTimeScaleInDay =  4.0_DP

    ! NAMELIST ����粋昭��
    ! NAMELIST is input
    !
    if ( trim(namelist_filename) /= '' ) then
      call FileOpen( unit_nml, namelist_filename, mode = 'r' ) ! (in)

      rewind( unit_nml )
      read( unit_nml, nml = held_suarez_1994_nml, iostat = iostat_nml )        ! (out)
      close( unit_nml )

      call NmlutilMsg( iostat_nml, module_name ) ! (in)
!$      if ( iostat_nml == 0 ) write( STDOUT, nml = held_suarez_1994_nml )
    end if

    ! 篆��違��┃絎�
    ! Configure coefficients
    !
    Kappa = GasRDry / CpDry

    P0          = 1000.0e2_DP
    DelTempY    = 60.0_DP
    DelPotTempZ = 10.0_DP

!!$    kf     = 1.0_DP / day_seconds
!!$    ka     = 1.0_DP / ( 40.0_DP * day_seconds )
!!$    ks     = 1.0_DP / (  4.0_DP * day_seconds )
    kf     = 1.0_DP / ( kfTimeScaleInDay * day_seconds )
    ka     = 1.0_DP / ( kaTimeScaleInDay * day_seconds )
    ks     = 1.0_DP / ( ksTimeScaleInDay * day_seconds )

    allocate( z_kv (1:kmax) )
    z_kv = kf * max( 0.0_DP, ( z_Sigma - SigmaB ) / ( 1.0_DP - SigmaB ) )

    allocate( yz_kt (1:jmax, 1:kmax) )

    do k = 1, kmax
      do j = 1, jmax
        yz_kt(j,k) = ka + ( ks - ka ) * max( 0.0_DP, ( z_Sigma(k) - SigmaB ) / ( 1.0_DP - SigmaB ) ) * cos( y_Lat(j) ) ** 4
      end do
    end do


    ! ���鴻�������若�水�阪�����������吾����亥�脂��
    ! Register of variables for history data output
    !
    call HistoryAutoAddVariable( 'DUDtHS94', (/ 'lon ', 'lat ', 'sig ', 'time' /), 'eastward wind tendency', 'm s-2' )
    call HistoryAutoAddVariable( 'DVDtHS94', (/ 'lon ', 'lat ', 'sig ', 'time' /), 'northward wind tendency', 'm s-2' )
    call HistoryAutoAddVariable( 'DTempDtHS94', (/ 'lon ', 'lat ', 'sig ', 'time' /), 'temperature tendency', 'K s-1' )
    call HistoryAutoAddVariable( 'TempEQHS94', (/ 'lon ', 'lat ', 'sig ', 'time' /), 'equilibrium temperature', 'K' )

    ! �医� ; Print
    !
    call MessageNotify( 'M', module_name, '----- Initialization Messages -----' )
    call MessageNotify( 'M', module_name, 'SigmaB           = %f', d = (/ SigmaB /) )
    call MessageNotify( 'M', module_name, 'kfTimeScaleInDay = %f', d = (/ kfTimeScaleInDay /) )
    call MessageNotify( 'M', module_name, 'kaTimeScaleInDay = %f', d = (/ kaTimeScaleInDay /) )
    call MessageNotify( 'M', module_name, 'ksTimeScaleInDay = %f', d = (/ ksTimeScaleInDay /) )

    call MessageNotify( 'M', module_name, '-- version = %c', c1 = trim(version) )

    held_suarez_1994_inited = .true.

  end subroutine HS94Init

Private Instance methods

DelPotTempZ
Variable :
DelPotTempZ :real(DP)
: $ (Delta theta)_z $ . 莎ら�������������贋�劫����県篏�綏�
DelTempY
Variable :
DelTempY :real(DP)
: $ (Delta T)_y $ . 罐泣��気����県綺�勲
Kappa
Variable :
Kappa :real(DP)
: $ kappa = R/C_p $ . 羂�篏�絎��違����ф��宴�������罸�. Ratio of gas constant to specific heat
P0
Variable :
P0 :real(DP)
: $ p_0 $ .
held_suarez_1994_inited
Variable :
held_suarez_1994_inited = .false. :logical, save
: ����荐���������. Initialization flag
module_name
Constant :
module_name = ‘held_suarez_1994‘ :character(*), parameter
: �≪�吾�ャ�若������腱�. Module name
version
Constant :
version = ’$Name: $’ // ’$Id: held_suarez_1994.f90,v 1.14 2012/04/27 11:24:45 noda Exp $’ :character(*), parameter
: �≪�吾�ャ�若�������若�吾�с�� Module version
yz_kt
Variable :
yz_kt(:,:) :real(DP), allocatable
: $ k_T $ .
z_kv
Variable :
z_kv(:) :real(DP), allocatable
: $ k_v $ .